[Bot] World of Warcraft Spotlight

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

I will be including lure application in the next Fish Bot release. Please view previous posts.

Fish bot will be released sometime saturday or sunday.

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

Done with another section. It is called GhostData. I will include a portion of the mainframe as well so you can see what it does.

GhostData can be ran as a standalone for updating the environment non stop as it was originally developed, however Spotlight calls it with a -update command to manually update it incase the user accidently closes GhostData.

GhostData Source

Code: Select all

#NoTrayIcon
Global Const $Ini = @ScriptDir & "\Settings.ini"
Global $Stamp = TimerInit(), $WinNew = -1, $WinOld = -1
#include <Array.au3>
_ArraySearch($CmdLine, "-update")
If Not @Error Then Exit
#Include <Misc.au3>
#Include <Detection Engine.au3>
_Singleton("GhostData")
AdlibEnable("ReduceMemory")
Update()
While 1
   WinResult()
   Select
      Case $WinNew <> $WinOld
         IniWrite($Ini, "Spotlight Data", "SpotlightActive", $WinNew)
         $WinOld = $WinNew
      Case $WinOld = 1 And $WinNew = 1 And TimerDiff($Stamp) >= 5000
         Update()
   EndSelect
   If _IsPressed("1B") Then Exit
   WEnd
Func OnAutoItExit()
   IniWrite($Ini, "Spotlight Data", "SpotlightActive", WinResult())
   Update()
EndFunc
Func Update()
   IniWrite($Ini, "Spotlight Data", "SpotlightWinHandle", WinGetHandle("Spotlight"))
   IniWrite($Ini, "Spotlight Data", "SpotlightProcess", WinGetProcess("Spotlight"))
   IniWrite($Ini, "Spotlight Data", "SpotlightStamp", $Stamp)
EndFunc   ;==>Update
Func WinResult()
   If WinExists("Spotlight") And ProcessExists("Spotlight.exe") Then $WinNew = 1
   If Not WinExists("Spotlight") And Not ProcessExists("Spotlight.exe") Then $WinNew = 0
   Return $WinNew
EndFunc   ;==>WinResult

GhostData Executable

Code: Select all

http://rapidshare.com/files/68607940/GhostData.exe.html

The mainframe example will be in the next post.

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

Mainframe

Code: Select all

#cs ----------------------------------------------------------------------------
   
   AutoIt Version: 3.2.9.3 (beta)
   Author:         AutoIt Smith
   Company:       ITS Games LLC
   
   Information:
   Spotlight - a World of Warcraft automation engine.
   
   Todo:
   Make sure entire GUI is built per Desktop Resolution.
   Make sure no CPU Spike.
   
#ce ----------------------------------------------------------------------------
AutoItSetOption("MustDeclareVars", 1)
AutoItSetOption("TrayMenuMode", 1)
#Include <GUIConstants.au3>
#Include <Array.au3>
#Include <File.au3>
#Include <Misc.au3>
#Include <Detection Engine.au3>
_Singleton("Spotlight")
Global $TransAble = TransTest ()
Global $AddGUI[1][3]
Global Const $Ini = @ScriptDir & "\Settings.ini"
Global $Action = "Wait", $CurrentStamp, $Height = @DesktopHeight, $Msg, $Number, $Title = "Spotlight", $Transparency = 255, $TransBuff = $Transparency, $TrayMsg, $Width = @DesktopWidth / 4
Global $GUI = GUICreate($Title, $Width, $Height - (@DesktopHeight / 15), @DesktopWidth - ($Width + 7.5), 0)
Global $File = GUICtrlCreateMenu("File")
Global $ExitMenu = GUICtrlCreateMenuitem("Exit", $File, 0)
Global $IMG = GUICtrlCreatePic(@ScriptDir & "\Images\Logo.jpg", 10, 10, $Width - 20, @DesktopHeight / 4, $SS_CENTERIMAGE)
Global $Status = GUICtrlCreateLabel("Status", 0, $Height - @DesktopHeight / 10 - 5, $Width, 15, BitOR($ES_CENTER, $ES_READONLY, $SS_SUNKEN))
Global $Tab = GUICtrlCreateTab(10, @DesktopHeight / 4 + 20, $Width - 20, $Height - @DesktopHeight / 2.75 - 20)
Global $Addons = GUICtrlCreateTabItem("Addons")
Global $View = TrayCreateMenu("Spotlight Visibility")
Global $Show = TrayCreateItem("Show Spotlight", $View, 0)
If $TransAble = 1 Then Global $Trans = TrayCreateItem("Set Transparency - Current " & $Transparency & " of 255", $View, 1)
Global $Hide = TrayCreateItem("Hide Spotlight", $View, 2)
Global $ExitTray = TrayCreateItem("Exit")
GenerateAddons()
GUISetState()
AdlibEnable("ReduceMemory")
IniWrite($Ini, "Spotlight Data", "SpotlightActive", 1)
Run(@ScriptDir & "\GhostData.exe")
While 1
   $CurrentStamp = IniRead($Ini, "Spotlight Data", "SpotlightStamp", -1)
   If TimerDiff($CurrentStamp) >= 5000 and Not ProcessExists("GhostData.exe") Then Run(@ScriptDir & "\GhostData.exe -update")
   _OneWindow (WinGetHandle($Title))
   Msg()
WEnd
Func ContinueAction()
   Select
      Case $Action = "Wait"
         ; Waiting for another action.
         Sleep(0x000000)
   EndSelect
EndFunc   ;==>ContinueAction
Func GenerateAddons()

EndFunc   ;==>GenerateAddons
Func Msg()
   Local $NewTrans, $Pos = WinGetPos($Title)
   If $TransBuff <> $Transparency Then TrayItemSetText($Trans, "Set Transparency - Current " & $Transparency & " of 255")
   $TransBuff = $Transparency
   $Msg = GUIGetMsg()
   $TrayMsg = TrayGetMsg()
   Select
      Case $Msg = $GUI_EVENT_CLOSE Or $Msg = $ExitMenu Or $TrayMsg = $ExitTray
         $Transparency = "Exiting..."
         MsgBox(0, "Goodbye!", "Thank you for using Spotlight for World of Warcraft." & @CRLF & "Don't forget to visit our site : http://www.itsgames.tk/")
         Exit
      Case $Msg = $GUI_EVENT_MINIMIZE Or $TrayMsg = $Hide
         $Transparency = 100
         GUISetState(@SW_HIDE, $GUI)
      Case $Msg = $GUI_EVENT_MAXIMIZE Or $Msg = $GUI_EVENT_RESTORE Or $Msg = $GUI_EVENT_RESIZED Or $TrayMsg = $Show
         $Transparency = 255
         WinSetTrans($Title, "", $Transparency)
         GUISetState(@SW_SHOW, $GUI)
         WinMove($Title, Default, $Pos[0], $Pos[1], $Width, $Height, 0)
         WinActivate($Title)
      Case $TransAble = 1 And $TrayMsg = $Trans
         $NewTrans = Number(InputBox($Title, "What will the new window transparency be?" & @CRLF & "Must be a valid integer between 100 and 255." & @CRLF & "100 is full transparency, 255 is full view."))
         If @error = 0 And $NewTrans <= 255 And $NewTrans >= 0 And IsInt($NewTrans) Then
            $Transparency = $NewTrans
            WinSetTrans($Title, "", $NewTrans)
            GUISetState(@SW_SHOW, $GUI)
            WinMove($Title, Default, $Pos[0], $Pos[1], $Width, $Height, 0)
            WinActivate($Title)
         EndIf
      Case Else
         ContinueAction()
   EndSelect
EndFunc   ;==>Msg
Func OnAutoItExit()
   Run(@ScriptDir & "\GhostData.exe -update")
   AdlibDisable()
   GUIDelete($GUI)
EndFunc   ;==>OnAutoItExit

Mainframe Executable

Code: Select all

http://rapidshare.com/files/68608936/Spotlight.exe.html

Mainframe compiles into Spotlight.exe

*Warning* SPOTLIGHT WILL NOT WORK UNLESS COMPILED INTO SPOTLIGHT.exe. Will be prebuilt into Mainframe in the next update.

Detection Engine (Put in Include Folder)
**REQUIRED TO COMPILE SPOTLIGHT**

Code: Select all

#cs ----------------------------------------------------------------------------
   
   AutoIt Version: 3.2.9.3 (beta)
   Author:         AutoIt Smith
   Company:       ITS Games LLC
   
   Information:
   Detection Engine built to detect environmental variables with AI using Desktop Resolution as base.
   
#ce ----------------------------------------------------------------------------
#Include-once
Global $Win = FindWindow()
Func CutExt($FileName)
   Return StringLeft($FileName, StringInStr($FileName, ".au3") - 1)
EndFunc   ;==>CutExt
Func _DirGetFiles($Directory)
   Local $Info = _ArrayCreate("Number"), $NewFind, $Search = FileFindFirstFile($Directory)
   $Info[0] = 0
   While 1
      $NewFind = FileFindNextFile($Search)
      Select
         Case Not @error
            If $NewFind <> "Detection Engine.au3" Then
               _ArrayAdd($Info, CutExt($NewFind))
               $Info[0] += 1
            EndIf
         Case @error
            ExitLoop
      EndSelect
   WEnd
   Return $Info
   
EndFunc   ;==>_DirGetFiles
Func FindWindow()
   Local $Class = "[CLASS:GxWindowClassD3d]", $Window[3]
   Select
      Case WinExists($Class) And ProcessExists(WinGetProcess($Class))
         $Window[0] = WinGetTitle($Class)
         $Window[1] = WinGetHandle($Class)
         $Window[2] = WinGetProcess($Class)
         Return $Window
      Case Else
         ; Window Not Found
         SetError(-1)
         Return -1
   EndSelect
EndFunc   ;==>FindWindow
Func _GuiRoundCorners($h_win, $i_x1, $i_y1, $i_x3, $i_y3)
   ; Written by gafrost.
   Local $XS_pos, $XS_ret, $XS_ret2
   $XS_pos = WinGetPos($h_win)
   $XS_ret = DllCall("gdi32.dll", "long", "CreateRoundRectRgn", "long", $i_x1, "long", $i_y1, "long", $XS_pos[2], "long", $XS_pos[3], "long", $i_x3, "long", $i_y3)
   If $XS_ret[0]Then
      $XS_ret2 = DllCall("user32.dll", "long", "SetWindowRgn", "hwnd", $h_win, "long", $XS_ret[0], "int", 1)
   EndIf
EndFunc   ;==>_GuiRoundCorners
Func LogIn($Username = -1, $Password = -1)
   Local $XY = WinGetClientSize($Win[0])
   Local $LogInUserX = $XY[0] * 0.453512396694215
   Local $LogInUserY = $XY[1] * 0.570247933884298
   Local $LogInPassX = $XY[0] * 0.452479338842975
   Local $LogInPassY = $XY[1] * 0.672176308539945
   Local $LogInButtonX = $XY[0] * 0.5
   Local $LogInButtonY = $XY[1] * 0.75068870523416
   Select
      Case IsArray($Win)
         BlockInput(1)
         Sleep(1000)
         MouseClick("left", $LogInUserX, $LogInUserY, 1, 0)
         Sleep(1000)
         Send($Username)
         Sleep(1000)
         MouseClick("left", $LogInPassX, $LogInPassY, 1, 0)
         Sleep(1000)
         Send($Password)
         Sleep(1000)
         MouseClick("left", $LogInButtonX, $LogInButtonY, 1, 0)
         BlockInput(0)
      Case Not IsArray($Win)
         ; Window Could Not Be Found
         SetError(-1)
         Return -1
   EndSelect
EndFunc   ;==>LogIn
Func Launch($Directory)
   Run($Directory & "\WoW.exe")
   WinWait("[CLASS:GxWindowClassD3d]")
   WinActivate($Win[0])
   WinWaitActive($Win[0])
   WinMove($Win[0], "", 0, 0)
EndFunc   ;==>Launch
Func _Middle($Win)
   Local $size = WinGetClientSize($Win)
   If @error Then Return
   Local $x = (@DesktopWidth / 2) - ($size[0] / 2)
   Local $y = (@DesktopHeight / 2) - ($size[1] / 2)
   Return WinMove($Win, "", $x, $y)
EndFunc   ;==>_Middle
Func _OneWindow($w_High_Lander, $w_Kill_Close = 0, $i_IsVisible = 0)
   Local $w_Winlist
   ; Written by Sm0ke_N, updated for declaration of variables.
   If $w_High_Lander <> '' Then
      $w_Winlist = WinList()
      For $i = 1 To $w_Winlist[0][0]
         If $i_IsVisible = 0 Then
            If $w_Winlist[$i][0] == WinGetTitle($w_High_Lander) And $w_Winlist[$i][1] <> $w_High_Lander And BitAND(WinGetState($w_Winlist[$i][1]), 2) Then
               If $w_Kill_Close = 0 Then
                  WinKill($w_Winlist[$i][1])
               Else
                  WinClose($w_Winlist[$i][1])
               EndIf
            EndIf
         Else
            If $w_Winlist[$i][0] == WinGetTitle($w_High_Lander) And $w_Winlist[$i][1] <> $w_High_Lander Then
               If $w_Kill_Close = 0 Then
                  WinKill($w_Winlist[$i][1])
               Else
                  WinClose($w_Winlist[$i][1])
               EndIf
            EndIf
         EndIf
      Next
   EndIf
EndFunc   ;==>_OneWindow
Func ReduceMemory()
   ; Written by wOuter, updated for space.
   Local $ai_Handle = DllCall("kernel32.dll", 'int', 'OpenProcess', 'int', 0x1f0fff, 'int', False, 'int', -1)
   Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', $ai_Handle[0])
   DllCall('kernel32.dll', 'int', 'CloseHandle', 'int', $ai_Handle[0])
EndFunc   ;==>ReduceMemory
Func _Restart()
   ; Originally Written by UP_NORTH
   ; Rewritten and Adapted by AutoIt Smith
   If @Compiled = 1 Then Exit Run(FileGetShortName(@ScriptFullPath))
   If @Compiled = 0 Then Exit Run(FileGetShortName(@AutoItExe) & " " & FileGetShortName(@ScriptFullPath))
EndFunc   ;==>_Restart
Func SelectChar ($CharName)
   Local $XY = WinGetClientSize($Win[0])
   Local $EnterWorldX = $XY[0] * 0.49875
   Local $EnterWorldY = $XY[1] * 0.98
   ; Search for Char Name ( To Be Built)
   ; Currently only logs in for default character.
   MouseClick("left", $EnterWorldX, $EnterWorldY, 1, 0)
EndFunc   ;==>SelectChar
Func Time()
   Local $Hour = @HOUR
   Local $Light = " AM"
   Local $Minute = @MIN
   Local $Sec = @SEC
   If $Hour = 0 Then
      $Hour = 12
   ElseIf $Hour = 12 Then
      $Light = " PM"
   ElseIf $Hour > 12 Then
      $Hour = (@HOUR) - 12
      $Light = " PM"
   EndIf
   Local $Time = $Hour & ":" & $Minute & ":" & $Sec & $Light
   Return $Time
EndFunc   ;==>Time
Func TransferInfo($File)
   Local $FileFull = @ScriptDir & "\Addons\" & $File
   _FileWriteToLine($FileFull, 2, "Global Const $Stamp = " & TimerInit(), 1)
   _FileWriteToLine($FileFull, 3, "Global Const $GUI = " & $GUI, 1)
   _FileWriteToLine($FileFull, 5, '_Singleton("' & CutExt($File) & '")', 1)
EndFunc   ;==>TransferInfo
Func TransTest()
   If @DesktopDepth < 16 Then Return 0
   If @OSVersion <> BitOR("WIN_2000", "WIN_XP", "WIN_2003", "WIN_VISTA") Then Return 0
   Return 1
EndFunc   ;==>TransTest

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

Bump. Finished first post and hosted all files. Updates will be posted there from now on.

~Smith

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

I've had a major event happen in my life and need to apologize for lack of work on spotlight. Will be working more tomorrow.

But seriously, 600+ views and not a single post. cmon lol!

~Smith

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

Ok so the addon idea will not work.

I need someone who knows a bit more about memory stuff then I do. If anyone can write a piece of example code for simply reading the Hit Points, providing me with address and offset with a small explanation I should be able to finish Spotlight by this weekend. Currently I don't understand offsets and such very well.

Thanks.

Snarg · **Posted:** Thu Nov 15, 2007 2:22 am

AutoIt Smith wrote:

Ok so the addon idea will not work.

I need someone who knows a bit more about memory stuff then I do. If anyone can write a piece of example code for simply reading the Hit Points, providing me with address and offset with a small explanation I should be able to finish Spotlight by this weekend. Currently I don't understand offsets and such very well.

Thanks.

Next time you log on, look down the main index near the hacking section :)

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

Snarg wrote:

AutoIt Smith wrote:

Ok so the addon idea will not work.

I need someone who knows a bit more about memory stuff then I do. If anyone can write a piece of example code for simply reading the Hit Points, providing me with address and offset with a small explanation I should be able to finish Spotlight by this weekend. Currently I don't understand offsets and such very well.

Thanks.

Next time you log on, look down the main index near the hacking section

I'm not quite sure how to calculate addresses from offsets.

Carvio · **Joined:** Fri Nov 16, 2007 10:13 am

So is this safe as of patch 2.3?

Carvio · **Joined:** Fri Nov 16, 2007 10:13 am

So is this safe as of patch 2.3?

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

It's just a color bot. So.. yes it is safe as of 2.3 and later. Spotlight will be aimed at being more safe then glider.

Carvio · **Joined:** Fri Nov 16, 2007 10:13 am

AutoIt Smith wrote:

It's just a color bot. So.. yes it is safe as of 2.3 and later. Spotlight will be aimed at being more safe then glider.

Is the fishing bot included at the moment, or will it come this weekend?

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

Fisher will be completed after the detection engine is completed. Currently I'm doing some advanced research and I hope for it to be ready by the weekend, but you never know.

Just stay tuned.

P.S. I was afking in Shattrath and got banned. For sitting there to long apparently......now I really want blizzard to rot in hell.

Bump : Updated main page. Rebuilt and organized files. Hopefully more understandable. Merged MousePos into Generic Data Tool.

Deyn · **Joined:** Tue Jul 18, 2006 3:41 pm

I love what you are doing keep up the good work!

AutoIt Smith · **Joined:** Mon Dec 27, 2004 4:32 am

Deyn wrote:

I love what you are doing keep up the good work!

@Deyn - Thx!

Sorry for the lack of updates but with the holiday and school and parents...ugh.... no time. Addon system is complete and working however I need to build the GUI parser. If you know AutoIt well then please download the zip and review Mainframe.au3, and Addon Here.au3(Addon Template by any other name) and see if I'm doing the addon GUI right - if it should be a parser - is there a smarter way to do it - test for bugs and stuff.

The two known bugs should be fixed. One included setting Window trans according to title instead of handle, so if FolderView had something open it set the trans. Found that one while testing Spotlight with the folder open....LOL. The other bug was a reverse load system where addons wouldn't parse correctly and ended up running the loop into the ground. That's since been fixed. I do notice some lag between load and unload of Spotlight, as well as addons. Anyone who could give me a hint as to why it lags would be awesome.

I will be working on the project this weekend and hopefully will have the parser, and fisher done. Research is still going on in memory information for the detection and AI that will eventually be wrapped into the bot addon.

And a new addon is planned called Updater. Does exactly that. Updates Spotlight and it's certified addons.

Todo:
Addon certification.
Addon parser.
Clean up fisher and rebuild for efficiency.
Build Updater
Build Movement bot based on XML profiles - maybe we should move into a more secure form, and away from media standard? ideas? I wouldn't mind incorporating my old AdminDB project so information could be stored locally and securely, allowing for no internet contact of Spotlight - since there are no "trials" or fees.

I am working on the project design for an addon that will build a bot and find games primary values. But that is only a goal currently - thus why the released executables and files say Game Automation Engine instead of WoW Bot.

~Smith

Blizzhackers

[Bot] World of Warcraft Spotlight

Who is online